" Test whether glob()/globpath() return correct results with certain escaped
" characters.

func SetUp()
  " consistent sorting of file names
  set nofileignorecase
endfunction

function Test_glob()
  " This test fails on Windows because of the special characters in the
  " filenames. Disable the test on non-Unix systems for now.
  CheckUnix

  " Execute these commands in the sandbox, so that using the shell fails.
  " Setting 'shell' to an invalid name causes a memory leak.
  sandbox call assert_equal("", glob('Xxx\{'))
  sandbox call assert_equal("", 'Xxx\$'->glob())
  w! Xxx\{
  w! Xxx\$
  sandbox call assert_equal("Xxx{", glob('Xxx\{'))
  sandbox call assert_equal("Xxx$", glob('Xxx\$'))
  call delete('Xxx{')
  call delete('Xxx$')
endfunction

function Test_globpath()
  sandbox call assert_equal("sautest/autoload/globone.mnv\nsautest/autoload/globtwo.mnv",
        \ globpath('sautest/autoload', 'glob*.mnv'))
  sandbox call assert_equal(['sautest/autoload/globone.mnv', 'sautest/autoload/globtwo.mnv'],
        \ 'glob*.mnv'->globpath('sautest/autoload', 0, 1))
endfunction

" mnv: shiftwidth=2 sts=2 expandtab
